AppleScript i Acrobat

Tråden skapades och har fått 2 svar. Det senaste inlägget skrevs .
1
  • Medlem
  • 2003-11-03 12:38

Jag är tämligen rudis på AppleScript och har stött på ett problem. Jag försöker skriva ett AppleScript som öppnar ett dokument och lägger till sidor från ett annat. Det är Acrobats 'Insert Pages' som jag inte får att fungera. Så här det ut i mitt script:

open theFolder & ":dok1.pdf"
insert pages of document after 1 from theFolder & ":doc2.pdf"

Applescript svarar

--> Acrobat 5.0 got an error: document doesn't understand the insert pages message.

Jag gissar att jag inte lyckats lämna rätt referens till det öppna dokumentet. Några tips?

(*
INSERT PAGES IN ACROBAT
----------------------------------------------------------------
Av: Ola@intelligentmammals.se, 2003-11-03
http://www.intelligentmammals.se/

Detta är ett litet test för att sätta in PDF-filer inuti andra PDF-filer.

*)

tell application "Finder"
-- Låt användaren peka på en "target"
set targetalias to choose file with prompt "Vilken PDF vill du sätta in i?"
-- Lagra undan namnet på "target" för att kunna referera till den senare
set targetname to name of targetalias
-- Samma procedur för "source"
set sourcealias to choose file with prompt "Vilken PDF vill sätta in?"
set sourcename to name of sourcealias
end tell

tell application "Acrobat 6.0 Professional"
-- Öppna "target" i Acrobat
open targetalias
-- Skapa en referens till "target" av typen document
set targetdocument to document targetname
-- Läs av antalet sidor i "target"
set numberofpagesoftarget to page number of last page of targetdocument
-- Samma procedur för "source"
open sourcealias
set sourcedocument to document sourcename
set numberofpagesofsource to page number of last page of sourcedocument
-- Sätt in "source" i "target"
insert pages targetdocument after numberofpagesoftarget from sourcedocument starting with 1 number of pages numberofpagesofsource
-- Spara och stäng
close all docs saving yes
end tell

tell application "Finder"
display dialog "I'm done, let's sing a song!"
end tell

Enjoy!

/Ola

  • Medlem
  • 2003-11-04 17:51

Tack Ola, jag ska prova när jag fått hem Acrobat 6.
Efter lite mer omfattande sökningar, hittade jag bara konstateranden att just insert pages i Acrobat 5's Applescript faktiskt inte fungerar.

1
Bevaka tråden