Denna delen av 99 uppdateras inte längre utan har arkiverats inför framtiden som ett museum.
Här kan du läsa mer om varför.
Mac-nyheter hittar du på Macradion.com och forumet hittar du via Applebubblan.

Kan regel fånga gamla mail i Outlook?

Tråden skapades och har fått 7 svar. Det senaste inlägget skrevs .
1
  • Medlem
  • 2015-01-29 14:55

Jag vill skapa en regel som fångar mail i inkorgen som är x dagar gamla och flyttar dem till en lokal mapp, men reglerna gäller bara nya mail, om jag läser rätt.
Hur löser man detta? Jag är inte främmande för att applescripta, men när jag försöker lyckas jag inte identifiera om mailat ligger i den lokala inkorgen eller på servern.

  • Medlem
  • International user
  • 2015-01-29 15:16
Ursprungligen av Baron:

Jag vill skapa en regel som fångar mail i inkorgen som är x dagar gamla och flyttar dem till en lokal mapp, men reglerna gäller bara nya mail, om jag läser rätt.
Hur löser man detta? Jag är inte främmande för att applescripta, men när jag försöker lyckas jag inte identifiera om mailat ligger i den lokala inkorgen eller på servern.

Jag har försökt på windows och det är fullkomligt omöjligt. Om jag minns rätt så är det fullt möjligt att skapa regeln, men den fungerar inte då de enbart verkar gå att köra på nyanlända mail.

Löser du detta utan Applescript vill jag veta hur du gör det.

Jag antar du kör mot exchange server när du kör outlook, isåfall behöver du verkligen identifiera det, är inte den lokala bara en spegling av vad severn har? Och kommer inte vad du gör lokalt att speglas till servern?

Det brukar finns bland de sista valen man kan kryssa i skapandet av regel.

Applicera på nuvarande/gamla mail.

Man markerar de mail man vill bearbeta med regeln, och så kör man den. Svårare än så är det inte

  • Medlem
  • International user
  • 2015-01-30 09:48
Ursprungligen av Richard Rönnbäck:

Man markerar de mail man vill bearbeta med regeln, och så kör man den. Svårare än så är det inte

Vilket är fullständigt värdelöst, då kan jag lika gärna flytta dem manuellt. Outlook är rena skräpet, om jag bara kunde köra Apples mail på jobbet vilken dröm det skulle vara.

Vad jag vill ha är att mail som har en viss kategori, ska flyttas till en mapp när de är mer än två veckor gamla. Super enkelt att göra med Apples mail. Men med skithögen outlook nej.

  • Medlem
  • International user
  • 2015-01-30 09:50
Ursprungligen av Borttaget:

Det brukar finns bland de sista valen man kan kryssa i skapandet av regel.

Applicera på nuvarande/gamla mail.

Tyvärr inte, inte i outlook som är del av Office professional plus 2013. Jag gick just igenom reglerna.
Eller jo det finns, men det går inte att få den att köra automatist på mail som är t.ex. två veckor gamla.

Senast redigerat 2018-07-23 13:04
  • Medlem
  • 2015-02-05 12:29

Jag har på lediga stunder pysslat lite. kanske tom @Richard Rönnbäck kan vara intresserad. Jag kör det schemalagt så slipper jag fundera på det:

-- set theFolders to {{{"Exchangekonto", "Brevlåda"}, "Arkivmapp"}, {{"Exchangekonto", "Brevlåda 2"}, "Arkivmapp 2"}}
set theFolders to {{{"Sydsvenskan", "Inkorgen"}, "Arkiv - Inkorgen"}, {{"Sydsvenskan", "Skickat"}, "Arkiv - Skickat"}}

set theNumberOfDaysToSaveInSourceFolder to 365
set theNumberOfMovedMessagesToDisplay to 20
set theShowMoveCountState to true
set theShowErrState to true

-------------------------------------------------- 


set theKeepLimit to ((current date) - theNumberOfDaysToSaveInSourceFolder * days)
set theErrMsg to ""
set theMoveCount to 0
tell application "Microsoft Outlook"
	repeat with theFolder in theFolders
		set {theSourceAccount, theSourceFolder, theTargetFolder} to {item 1 of item 1 of theFolder, item 2 of item 1 of theFolder, item 2 of theFolder}
		set theFolderCheck to (my doPreflight(theSourceAccount, theSourceFolder, theTargetFolder))
		if theFolderCheck is true then
			set theMessagesToMove to (messages of mail folder theSourceFolder of exchange account theSourceAccount whose time received < theKeepLimit)
			set theMoveCount to (count theMessagesToMove)
			set theSubjects to ""
			repeat with theItem in theMessagesToMove
				set theSubjects to theSubjects & "Till " & theTargetFolder & ": " & subject of theItem & return
				move theItem to mail folder theTargetFolder of on my computer
			end repeat
		else
			if theErrMsg is "" then
				set theErrMsg to theErrMsg & theFolderCheck
			else
				set theErrMsg to theErrMsg & return & theFolderCheck
			end if
		end if
	end repeat
	
	if theErrMsg is not "" and theShowErrState is true then
		display alert "Okänt fel" message theErrMsg buttons {"OK"}
	end if
	
	if theShowMoveCountState is true then
		if theMoveCount > theNumberOfMovedMessagesToDisplay then
			set theSubjects_trunkated to (my doMakeStringOfList(paragraphs 1 thru theNumberOfMovedMessagesToDisplay of theSubjects, return))
			set theSubjects_trunkated to theSubjects_trunkated & return & return & "… och " & (theMoveCount - theNumberOfMovedMessagesToDisplay) & " ytterligare meddelanden."
			set A to display alert (theMoveCount as string) & " meddelanden arkiverade" message theSubjects_trunkated buttons {"OK"} giving up after 60
		else
			set A to display alert (theMoveCount as string) & " meddelanden arkiverade" message theSubjects buttons {"OK"} giving up after 60
		end if
	end if
end tell

on doPreflight(theSourceAccount, theSourceFolder, theTargetFolder)
	set theErr to {}
	tell application "Microsoft Outlook"
		try
			get exchange account theSourceAccount
			try
				get folder theSourceFolder of exchange account theSourceAccount
			on error err
				set end of theErr to err
			end try
		on error err
			set end of theErr to err
		end try
		
		try
			get folder theTargetFolder of on my computer
		on error err
			set end of theErr to err
		end try
	end tell
	if theErr is {} then
		return true
	else
		return (my doMakeStringOfList(theErr, return))
	end if
end doPreflight

on doMakeStringOfList(T, del)
	tell me to set oldTID to text item delimiters
	tell me to set text item delimiters to del
	set T to T as string
	tell me to set text item delimiters to oldTID
	return T
end doMakeStringOfList
Senast redigerat 2015-02-05 13:07
  • Medlem
  • International user
  • 2015-02-09 12:47

Om man ändå kunde köra Applescript på windows

1
Bevaka tråden