Mobilkamera - iphoto - .mac

Vid en snabb genomläsning av ordlistan i Mail så ser jag inte direkt om det är möjligt att "komma åt" en eller flera bilagor till ett inkommande mail och spara undan dem. Det man direkt kan utläsa är att det går via Applescript att skapa ett nytt meddelande med en bilaga. Så här står det:

Class attachment: Represents an inline text attachment. This class is used mainly for make commands.

Men om man struntar i mail så vet jag att det går i Entourage och via FileMaker Pro (utrustad med pluginen POPIt).

Så ja, det går att göra.

/Ola

Problemet kan väl vara att scripta iPhoto uppladdning till .mac, men det kanske man kan fixa med Apples GUI Scripting.

Jag tror att det är möjligt att skapa ett album antingen via iPhoto eller något annat program (det är väl bara bilder och html eller hur?) och sedan ladda upp det via antingen Goliath (Web-DAV-klient, som jag inte kollat om den går att scripta), eller den WebDAV-klient som är inbyggd i systemet.

Vad jag menade var att det är möjligt att maila bilder från sin mobiltelefon och ha någon typ av "snurra" (FM-term faktiskt...) som laddar hem mailen, sparar ner bilagorna, skapar en webbsida och laddar upp resultatet på ett .mac-konto.

/Ola

En delmängd av ditt problem är faktiskt löst i denna diskussion:

http://99mac.com/forum/showthread.php?s=&threadid=26988

Den delen som handlar om att spara ner bilagorna som kommer med ett mail som filer på valfritt ställe (i exemplet används skrivbordet). Dock används i diskussionen Entourage och inte Mail, men det borde inte vara så svårt att bygga om scriptet för Mail, förutsatt att de kommandon man behöver finns tillgängliga där.

Enjoy!

/Ola

Kul ide!

Det är sent här men jag var tvungen att styra upp ett litet skript. Detta funkar men förutsätter att html-sidan redan finns och kan hantera bilder med namn 1.gif, 2.gif osv i viss storlek.

Man kan bygga på med fler bilder från mobben så långt man förberett i htmlen.

Jag använder Entourage och Interarchy. Skall kommentera och snygga till det lite imorgon samt ordna och testa från mobben. Skulle vara coolt att lägga till bildtext (från subject) men då måste man pilla med htmlen..

tell application "Finder"
activate
set antalBilder to number of items of folder "henry:Users:mattan:Desktop:mobbe:"
set nastabild to antalBilder + 1 as string
end tell

tell application "Microsoft Entourage"
activate
set listofattachments to attachments of message 1 of folder "bild"
repeat with oneattachment in listofattachments
-- Gör saker med varje bilaga här:
save oneattachment in ("henry:Users:mattan:Desktop:mobbe:" & nastabild & ".gif") as file type of oneattachment
set bilden to ("henry:Users:mattan:Desktop:mobbe:" & nastabild & ".gif") as alias
end repeat
move message 1 of folder "bild" to folder "uppladdad"
end tell

tell application "Interarchy 5.0.1"
activate
-- if size of item ("henry:Users:mattan:Desktop:mobbe:" & nastabild & ".jpg") < 150 then Funkade inte!
store bilden url "ftp://USERID:PWD@SERVER/mobilbilder/thumbnail..."
-- end if
end tell

Applescript är kul!!

O.K. så här gjorde jag, utan AS.
Skapade en regel i Entourage. Om avsändaren är XX och ämnet är Fastweb, spara bifogade fil, i destinationen angav jag en mapp på iDisc / Pictures som jag kallar tex. Mobilbilder. Sedan skapar jag en ny Webbsida som jag kallar Mobilen.

Nu då jag skickat bilden till min dator, som naturligtvis har Entourage gående och som kollar mailen varje minut, iDiscen måste naturligtvis också vara monterad, så behöver jag bara logga in på mitt .mac-konto och uppdatera webbsidan Mobilen genom att bara välja mappen Mobilbilder. Vips nya bilder på sidan.

Ok, nu har jag snyggat till och utvecklat scriptet lite. Jag lade till en resize i Graphic Converter.

(* Ett applescript för att ladda upp bilder attachade till ett email i Entourage X mha av ftp i Interarchy 5, Graphic Converter och
en förberedd html-mall. Mallen kan se ut hur som helst men bilderna måste döpas enligt formen 1.jpg, 2.jpg osv...
//mattan
*)

-- Först kollar vi hur många bilder som redan laddats upp så att vi kan få fram numret som vår bild skall använda och inte ersätter gamla bilder

tell application "Finder"
activate
set antalBilder to number of items of folder "henry:Users:mattan:Desktop:Mobilbilder:"
-- Ger antal filer i den mapp vi angett för att spara bilderna
set nastabild to antalBilder + 1 as string
-- Sätter variabeln nastabild till nästa lediga nummer
end tell

(* Över till Entourage X där vi använder Ola's loop för att komma åt attachmentet. Jag har satt en mail
rule i Entourage som flyttar alla mail addresserad till mobilbild@mattan.net till mappen "mobilbilder"
och sen triggar detta script.
*)

tell application "Microsoft Entourage"
activate
set listofattachments to attachments of message 1 of folder "Mobilbilder"
-- Ger referens till alla attachment i mailet
repeat with oneattachment in listofattachments
-- Gör saker med varje bilaga här: OBS: Scriptet funkar egentligen bara med ETT attachment men jag lyckades inte få till det utan loopen
save oneattachment in ("henry:Users:mattan:Desktop:Mobilbilder:" & nastabild & ".jpg") as file type of oneattachment
-- sparar attachmentet i mappen "Mobilbilder med namn med rätt nummer och ändelse 1.jpg, 2.jpg etc.
set bilden to ("henry:Users:mattan:Desktop:Mobilbilder:" & nastabild & ".jpg") as alias
-- spara referens till bilden som vi använder senare Graphic Converter och Interarchy
end repeat
move message 1 of folder "Mobilbilder" to folder "Uppladdade mobilbilder"
-- flyttar meddelandet till en annan folder för arkivering
end tell

(* Nu öppnar vi bilden i Graphic Converter och skalar om den till 120 i bredd (på ett onödigt komplicerat sätt) och sparar som jpg
för det fall att den var i ett annat format.
*)

tell application "GraphicConverter"
activate
open bilden
get image dimension of window 1 -- Hämta storlek på bilden
set bildstorlek to the result -- Spara resultatet. Det sparas som en lista med 2 items
set skalfaktor to 120 / (item 1 of bildstorlek) -- Ta fram faktorn genom att dela 120 med bredd
set nyahojden to (item 2 of bildstorlek) * skalfaktor -- Ta fram ny skalenlig höjd
set image dimension of window 1 to {120, nyahojden} -- Skala om bilden
save window 1 as JPEG -- Spara bilden
quit
end tell

-- Nu är bilden fixad och sparad på datorn. Över till Interarchy för att ladda upp den på web-servern via ftp

tell application "Interarchy 5.0.1"
activate
store bilden url "ftp://USERID:[email protected]/mobilbilder/..."
-- Laddar med kommandot "store url" upp bilden (vår referens till filen) på webserven
quit
end tell

Om det är ngn som är ute och snurrar med sin kameramobil (eller sitter hemma) så skicka ett mail med en bild till: mobilbild_at_mattan.net

Din bild dyker upp på:

http://mattan.net/mobilbilder/index.html

Efter max 10 minuter. Look no hands

Skriptet borde vara ganska lätt att modda för Mail+iDisk.

Jag sitter nu och pular med att även skapa/ladda upp html-koden så att jag kan få med datum eller bildtext på sidan. Ngn som vet en tutorial för Textedit? Jag har fruktansvärda problem

Så här hade jag tänkt göra i första versionen:

- Klistra in header
- göra en loop baserad på bildnamn (från vilken jag vet hur många bilder som redan ligger på sidan) som skapar IMG-taggarna
- Klistra in resultat
- Klistra in footer
- Spara/ladda upp tillsammans med bilden

Mycket tjusigt Mattan! Kul att se att något av det jag skrev faktiskt var till nytta för någon annan.

En variant av detta kan ju vara att skapa en mapp för varje dag på servern, då finns tex dagens bilder i samma mapp. Du får gärna starta en ny tråd om datum i Applescript så kan jag kanske bidra där lite grann. Jag har pillat lite med datum förut nämligen i Applescript.

När man skickat några 100 bilder så blir nog sidan lite lång att ladda... Men tanken kanske är att man skall gå in och fixa lite själv då och då...

Att producera lite text-filer (dvs html) borde inte vara så svårt. En variant kan ju vara att man utifrån ett malldokument gör sök och ersätt efter vissa specifika saker (XXYYZZ betyder att här skall bildtext infogas) och producerar ett nytt dokument på rätt ställe med rätt namn. Du kan tex ha en mall-sida för index-sida med datum och sedan en mall-sida per bild eller per dag,l komplett med små pilar och sådant till nästa sida. Borde gå. Kanske vi skall starta en ny tråd om scriptning av TextEdit för att skapa HTML-sidor?

/Ola

Nu får du inte vara blygsam...

...utan din hjälp och tutorials så hade jag fortfarande varit kvar på "newbie som inte gjort ett enda script som funkar"-stadiet

Både mapp och datum idéerna låter kanon men först vill jag nog hålla mig till att göra en html-sida

Låter bra med en ny tråd för textbehandling. Jag startar med ett inlägg, kom på ett ganska mkt enklare sätt att göra det (tror jag).

//mattan

På http://www.diepunyhumans.com/ finns, i alla fall i dag och några dagar till, några tips om redan existerande lösningar för det här.

För säkerhets skull klistrar jag även in texten nedan.

Ett annat ställe är http://www.textamerica.com/register.asp?mlog=1 Det finns säkert fler.

"How Futurephoning Works

I'm getting a lot of email about this, so here's a quick outline of what
I'm doing.

You need a phone that can send email with attachments. If you want to
publish photos from phone to blog, you can't use something like Sprint's
"picture share," because it's dependent on links that will not work.

I use the mfop2 system found at http://www.bastish.net/mfop. Their system
works with Movable Type, Blogger and maybe a couple more, I forget.
Functionality with Blogger is spotty, due to Blogger's instability.

Go there and set yourself up an account, which involves filling out a form
giving your connection details. This is going to be a trial-and-error
thing. You'll need to create a directory on your website for photos to be
sent to. Note; mfop does not rename images. My Nokia 3650 assigns images
a number dependent on what's already in memory. If you're not careful,
you'll end up sending an Image(09).jpg to a directory that already has an
Image(09).jpg in it, and the latter will overwrite the former.

If you get it all working, you'll have associated the email address of your
phone with a system to publish to your blog. Mfop2 looks for your email
address and the password that must be on the first line of the message
body, and it'll publish everything else to your blog.

If it's just a photo, it'll throw the image into the directory and publish
to your blog the code that turns it into an inline image.

If it's just text, like this, it'll publish through as plain text.

I'm not sure if it'll work through MMS -- I've just sent a plain-text MMS
to mfop, we'll see if it works.

This will work on any email system associated with your phone's email
address. I'm writing this on my handheld's email client; it'll send
through my phone's email address.

If you want to work solely through MMS, the easiest way is to set up a log
at www.textamerica.com. TA also renames images for you automatically.

I don't know how to get the published images to publish in a reduced size,
so you're stuck with the big images for now.

That should help.

-- W

Posted by Warren at 03:17 PM | TrackBack (0)"

Vissa av de problem som den färdiga lösningen har som Pelle tipsar om är faktiskt löst i det Applescript som mattan har gjort. Dels problemet med att döpa om bilderna och dels problemet med att skala om dem.

Men det är intressant att flera metoder finns att åstadkomma samma sak.

/Ola

Ok, nu är scriptet klart. Här kommer den slutliga koden.

(* Ett applescript för att ladda upp bilder+html-sidor attachade till ett email i Entourage X mha av ftp i Interarchy 5,
Graphic Converter och BBedit 7. Scriptet skapar sidor med 12 bilder i 4 kolumner med en bildbredd på 180 pixlar och arkiverar/länkar till de gamla sidorna. Bildtext tas från subject i emailet och uppladningsdatum läggs till automatiskt. Scriptet förutsätter en existerande index.html med samma
innehåll som variablen html_code nedan. Scriptet triggas lämpligtvis av en mail rule i Entourage X. Tack till Ola för all hjälp!
//mattan
*)

(*
Först sätter vi properties enligt följande:
jpg_source_folder - Mappen där jpgs skall sparas
ent_inbox - Namnet på mappen i Entourage där emailet sparas
ent_archive - Namnet på mappen i Entourage där emailen arkiveras
html_source_folder - Mappen där htmfil sparas
jpg_url - Adress dit jpgs skall sparas
html_url - Adress dit htmlfil sparas
html_code_1 - Kod som skall in före ny bild
html_code_2 - Kod som in efter ny bild
marker1 - Coment-tag där ny bildkod skall in.
html_code - Htmlkod för sidan i startläge . Kan ändras fritt men måste innehålla ,
och
*)

property jpg_source_folder : "henry:Users:mattan:Dokument MB:www.mattan.net:www Maj 2003:mobilbilder:images:"
property ent_inbox : "Mobilbilder"
property ent_archive : "Uppladdade mobilbilder"
property html_source_folder : "henry:Users:mattan:Dokument MB:www.mattan.net:www Maj 2003:mobilbilder:"
property jpg_url : "ftp://USERID:PASSWORD@HOST/PATH/"
property html_url : "ftp://USERID:PASSWORD@HOST/PATH/"
property html_code_1 : "<td width=\"200\"><img src=\"images/"
property html_code_2 : "\" alt=\"\" width=\"180\"><br><br><font color=\"000000\">"
property marker1 : ""
property html_code : "<html>
<head>
<title>Titel</title>
<meta http-equiv=Content-Type content=\"text/html; charset=iso-8859-1\">
</head>
<body>
<img src=\"/img/navbar.jpg\" width=700 height=20> <br>
<br>
<center>
<h2>Mobilbilder</h2><p>
<p>
<table border=\"0\" cellspacing=\"10\" cellpadding=\"10\">
<tr valign=\"bottom\"></tr></table>
</center>
</body>
</html>"

-- Kolla hur många bilder som redan laddats upp så att vi kan få fram numret som vår bild skall använda och inte ersätter gamla bilder

tell application "Finder"
set n to number of items of folder jpg_source_folder -- Ger antal filer i den mapp vi angett för att spara bilderna
set num_pic to n + 1 as string -- Sätter variabeln nastabild till nästa lediga nummer

-- Hämta och formatera dagens datum och formaterar som 2003-07-12. (script av Ola)

set toDay to current date
set DailyMonth to month of toDay -- Returnerar engelsk månad!
set monthsOfTheYear to {"January", "February", "March", "April", "May", "June", ¬
"July", "August", "September", "October", "November", "December"}
set monthnr to 0
repeat with monthName in monthsOfTheYear
set monthnr to monthnr + 1
if (DailyMonth as text) = (monthName as text) then
exit repeat
end if
end repeat
if monthnr < 10 then
set monthnr to "0" & (monthnr as text)
end if
set daynumber to day of toDay
if daynumber < 10 then
set daynumber to "0" & (daynumber as text)
end if
set DailyDate to (year of toDay & "-" & (monthnr as text) & "-" & daynumber) as string

end tell

-- Över till Entourage X där vi använder Ola's loop för att komma åt attachment och subject

tell application "Microsoft Entourage"
set text_pic to subject of message 1 of folder ent_inbox -- Spara ärenderaden i en variabel
set listofattachments to attachments of message 1 of folder ent_inbox
-- Ger referens till alla attachment i mailet
repeat with oneattachment in listofattachments
-- Gör saker med varje bilaga här: OBS: Scriptet klarar bara ETT attachment
save oneattachment in (jpg_source_folder & num_pic & ".jpg") as file type of oneattachment
-- Sparar attachmentet med rätt nummer och ändelse 1.jpg, 2.jpg etc.
set jpg_file_path to (jpg_source_folder & num_pic & ".jpg") as alias
-- Spara referens till bilden som vi använder senare Graphic Converter och Interarchy
end repeat
move message 1 of folder ent_inbox to folder ent_archive -- Arkivera emailet
end tell

-- Öppna bilden i Graphic Converter och skalar om den till 120 i bredd och sparar som jpg

tell application "GraphicConverter"
open jpg_file_path
set picDim to image dimension of window 1 -- Hämta storlek på bilden
set picHor to item 1 of picDim -- Spara resultatet
set picVert to item 2 of picDim -- Det sparas som en lista med 2 items
set newVert to round ((180 / picHor) * picVert) -- Ta fram ny skalenlig höjd
set image dimension of window 1 to {180, newVert} -- Skala om bilden
save window 1 as JPEG -- Spara bilden
close window 1
quit
end tell

-- Uppdatera html-filen med BBedit

tell application "BBEdit"
activate

-- IF-satsen triggas efter varje dussin bilder och sparar/laddar upp gamla sidan och skapar en ny sida med länk

if num_pic is greater than 2 then
if ((num_pic - 1) mod 12) = 0 then
tell application "Finder"
set html_file_path to html_source_folder & "index.html" as alias
set name of html_file_path to ("index" & (num_pic div 12) as string) & ".html"
set archive_file_path to (html_source_folder & "index" & (num_pic div 12) as string) & ".html" as alias
set new_link_html to ("<a href=\"index" & (num_pic div 12) as string) & ".html\">Older uploads</a>" as string
end tell
tell application "Interarchy 5.0.1"
store archive_file_path url html_url
quit
end tell
make new window
set selection to html_code
replace "" using new_link_html saving yes searching in window 1
set html_file_path to html_source_folder & "index.html"
save text window 1 to file html_file_path
close window 1
end if
else
beep
end if

-- Uppdatera index.html med kod för nya bilden

set html_file_path to html_source_folder & "index.html" as alias
open html_file_path
set new_html_code to html_code_1 & num_pic & ".jpg" & html_code_2 & text_pic & "</font><font color=\"FF9900\"> (" & DailyDate & ")</font></td>" & marker1
replace marker1 using new_html_code saving yes searching in html_file_path
close window 1

-- IF-satsen triggas var 4e bild och lägger till en ny rad i tabellen

if num_pic is greater than 2 then
if (num_pic mod 4) = 0 then
replace marker1 using "" saving yes searching in html_file_path
close window 1
replace "" using "<tr valign=\"bottom\">" & marker1 & "</tr>" saving yes searching in html_file_path
close window 1
end if
end if
save window 1
close window 1 -- Spara och stäng
quit
end tell

-- Till Interarchy för att ladda upp filerna till web-servern via ftp

tell application "Interarchy 5.0.1"
-- activate
store jpg_file_path url jpg_url
store html_file_path url html_url -- Laddar upp filerna på webserven
quit
end tell