Exempel på ett script som promenerar igenom alla mappar/filer man släpper på det och gör något med varje fil:
(*
UNLOCK ITEMS DROPPED ON IT
----------------------------------------------------------------
Av: Intelligent Mammals HB, 2002-10-14
Ola@intelligentmammals.se
http://www.intelligentmammals.se/
Detta manus låser upp alla filer som finns i de filer/mappar
man släpper på det eller som finns i den mapp man pekar
på. Det fungerar alltså både genom "drag and drop" och
genom att man dubbelklickar på det.
*)
(*
Om vi har släppt en massa filer och mappar på en
applet vi skapat av detta script så finns dem i
variabeln "fileList" som är av typen lista.
Denna variabel skickar vi till rutinen parseFiles.
*)
on open fileList
parseFiles(fileList) of me
end open
(*
Om vi har dubbelklickat på en applet av detta script
så får vi här istället upp en dialogruta för att välja
en mapp. När vi gjort det så finns en folder i variabeln
theFolderToParse. Vi skickar den mappen till rutinen
parseFolder.
*)
on run
choose folder
set theFolderToParse to the result
parseFolder(theFolderToParse)
end run
(*
Här tar vi ett objekt i taget och först kollar vi
om det är en mapp och om det är det så skickar vi
mappen till parseFolder. Annars är det en fil och
då låser vi upp den.
*)
on parseFiles(fileList)
tell application "Finder"
repeat with listItems in fileList
(*
Här kollar vi om objektet är en mapp
i så fall skickar vi det till en subrutin
för att få en lista på filer och mappar i
objektet.
*)
if kind of listItems is "mapp" then
set theFolderToParse to listItems
parseFolder(theFolderToParse) of me
else
(*
Här låser vi upp filen.
*)
set itemToUnlock to listItems
set locked of listItems to false
end if
end repeat
end tell
end parseFiles
(*
Kommer vi hit så har scriptet hittat en mapp. I så fall
så tar vi alla objekt i den mappen och skickar dessa
till parseFiles.
*)
on parseFolder(theFolderToParse)
tell application "Finder"
set newFileList to the items of theFolderToParse
parseFiles(newFileList) of me
end tell
end parseFolder
(*För att spara detta som en applet, dvs ett fristående program, så väljer du "Arkiv:Spara som" och under format väljer du "Program". Men spara först*)
Lycka till!
/Ola
